@echo off

Rem **************************************************************************
Rem Test if CMD Extensions are available
Rem **************************************************************************
verify other 2>nul
setlocal enableextensions
if errorlevel 1 (
  if not "%GUISTARTED%" == "1" (
    set GUISTARTED=1
    goto restartext
  )
)

Rem **************************************************************************
Rem Determine java executable
Rem **************************************************************************
if DEFINED JAVA_HOME (
  set JAVA_CMD="%JAVA_HOME%\bin\java"
) else (
  echo WARNING: Environment variable JAVA_HOME not set, try to launch java from current PATH.
  set JAVA_CMD=java
)

Rem **************************************************************************
Rem Get base directory
Rem **************************************************************************
set SDTGUI_HOME=%~dp0
set SDTGUI_HOME=%SDTGUI_HOME:"=%

Rem Save where we started
set OLDDIR=%CD%

cd /d %SDTGUI_HOME%
cd ..
set SDTGUI_HOME=%CD%

Rem **************************************************************************
Rem Setup stuff
Rem **************************************************************************

set SDTGUI_CLASSPATH=%SDTGUI_HOME%\lib\sdt_compatibility.jar
set SDTGUI_CLASSPATH=%SDTGUI_CLASSPATH%;%SDTGUI_HOME%\lib\sdt_gui.jar;%SDTGUI_HOME%\lib\sdt_lupgui.jar


%JAVA_CMD% -cp %SDTGUI_CLASSPATH% SDTGui service=SDTExecutionService %*

goto exit

Rem **************************************************************************
:restartext
echo *** Restarting script enabling CMD extensions
cmd /E:ON /C call %0 %*
goto exit

:exit