@echo off

rem *** Some variables
set bootstrap_fail=128
set bootstrap_need=4

set rootdir=%~dp0
cd /D %rootdir%

rem *** Check for java executable
set JAVA_CMD="/usr/sap/EPP/J00/exe/sapjvm_6\bin\java.exe"
set JSPM_JAVA_CMD="%JSPM_JAVA_HOME%\bin\java.exe"
rem *** Use local copy of SAPJVM if available
set LOCAL_JAVA=%rootdir%\sapjvm\jre\bin\java.exe

set useParentJVM=

if EXIST %JSPM_JAVA_CMD% (
rem *** Use copy of SAPJVM passed to the procedure
  set JAVA_CMD=%JSPM_JAVA_CMD%
  set LOCAL_JAVA=%JSPM_JAVA_CMD%
  set useParentJVM=-useParentJVM
) else (
	if NOT EXIST %JAVA_CMD% (
	  set JAVA_CMD="%JAVA_HOME%\bin\java.exe"
	)
	if NOT EXIST %JAVA_CMD% (
	  set JAVA_CMD=java
	)
	if NOT EXIST %LOCAL_JAVA% (
	  set LOCAL_JAVA=%JAVA_CMD%
	)
)

set restart= 
set continue= 

:again

rem *** Update JSPM and sync local copy of SAPJVM. Bootstraping
%JAVA_CMD% -ea -cp %rootdir%\bootstrap\lib\sdt_jspm_bootstrap.jar Jspm -boot=win %restart% %useParentJVM%
if ERRORLEVEL 1 (
  echo ERROR: could not update JSPM
  set rc=%bootstrap_fail%
  goto end
)

rem *** Start JSPM command-line
%LOCAL_JAVA% -ea -Xmx1024m -cp %rootdir%\lib\sdt_jspm_cmd.jar com.sap.sdt.jspm.cmd.main.JSPMCmd  %continue% %useParentJVM% %*
set rc=%ERRORLEVEL%
if %rc%==%bootstrap_need% (
  set restart=-restart
  set continue=continue
  goto again
)

:end
if "%CMDCMDLINE%" == "cmd /c %0 %*" exit %rc%
@echo on
exit /B %rc%